Minecraft存档转换助手

首先这是一个bat脚本
用途是 对于标准格式存档与Spigot格式存档相互转换

用法 需要复制到本体 （举例 复制到文本文件里 把扩展名.txt改成.bat

以下是脚本内容

::本脚本由熙光鸽鸽编写
:: 初始化

@echo off
cls
chcp 65001
echo.
echo 标准存档向Spigot转换请输入1
echo Spigot向标准存档转换请输入2
echo 删除指定名称存档请输入3
echo.
SET /P id="请输入您要进行的操作： "

2>NUL CALL :CASE_%id% 
IF ERRORLEVEL 1 CALL :DEFAULT_CASE 

ECHO Done.
EXIT /B

:CASE_1
    : 获取存档名字
    echo.
    set /p wn="请输入标准存档名字例如world："

    ::复制原存档以保证原文件安全
    echo.
    echo 复制原存档到临时文件夹中......
    xcopy .\%wn%\"*" .\%wn%_temp\ /s/y/q

    ::创建Spigot格式问价夹目录

    echo.
    echo 创建空白文件夹中......
    mkdir Spigot 
    mkdir .\Spigot\world\ 
    @REM mkdir .\Spigot\world_end\
    @REM mkdir .\Spigot\world_nether\
    mkdir .\Spigot\world_end\playerdata\
    mkdir .\Spigot\world_nether\playerdata\

    ::复制对应文件到对应位置

    echo.
    echo 正在复制文件到指定位置...请稍后...
    xcopy .\%wn%_temp\"*" .\Spigot\world\  /s/y/q
    rd .\Spigot\world\DIM1 /s/q
    rd .\Spigot\world\DIM-1 /s/q

    xcopy .\%wn%_temp\level.* .\Spigot\world_end\  /s/y/q
    xcopy .\%wn%_temp\level.* .\Spigot\world_nether\  /s/y/q

    xcopy .\%wn%_temp\session.lock .\Spigot\world_end\  /s/y/q
    xcopy .\%wn%_temp\session.lock .\Spigot\world_nether\  /s/y/q

    xcopy .\%wn%_temp\DIM1\"*" .\Spigot\world_end\DIM1\  /s/y/q
    xcopy .\%wn%_temp\DIM-1\"*" .\Spigot\world_nether\DIM-1\  /s/y/q
    rd .\Spigot\world_end\DIM1\playerdata /s/q
    rd .\Spigot\world_nether\DIM-1\playerdata /s/q

    ::删除临时文件

    echo.
    echo 删除临时文件中.....
    rd .\%wn%_temp /s/q

    echo.
    echo 温馨提示：运行过程中有些许错误正常,您的Spigot格式存档位于Spigot文件夹下 
    pause
    GOTO END_CASE
    ::********************************************************************************************************************************
:CASE_2

    :: 获取存档名字
    echo.
    set /p swn="请输入Spigot存档位于的文件夹，例如spigot（其中需包括三个维度的存档）："

    ::复制原存档以保证原文件安全
    echo.
    echo 复制原存档到临时文件夹中......
    xcopy .\%swn%\"*" .\%swn%_temp\ /s/y/q

    ::获取输出后问价夹名字

    echo.
    set /p rwn="请输入导出后文件夹的名字："

    ::创建文件夹

    echo.
    echo 创建空白文件夹中......
    mkdir %rwn% 
    mkdir .\%rwn%\DIM1\
    mkdir .\%rwn%\DIM-1\
    mkdir .\%rwn%\DIM1\playerdata\
    mkdir .\%rwn%\DIM-1\playerdata\

    ::复制文件到对应文件夹

    echo.
    echo 正在复制文件到指定位置...请稍后...
    xcopy .\%swn%_temp\world\"*" .\%rwn%\  /s/y/q
    xcopy .\%swn%_temp\world_end\DIM1\"*" .\%rwn%\DIM1\  /s/y/q
    xcopy .\%swn%_temp\world_nether\DIM-1\"*" .\%rwn%\DIM-1\  /s/y/q

    ::删除临时文件

    echo.
    echo 删除临时文件中.....
    rd .\%swn%_temp /s/q

    echo.
    echo 温馨提示：运行过程中有些许错误正常,您的标准格式存档位于%rwn%文件夹下 

    pause
    GOTO END_CASE
    ::*********************************************************************************************************************************

:CASE_3

    :: 获取存档名字
    echo.
    set /p dwn="请输入需要删除的存档名称："

    ::执行删除

    rd .\%dwn% /s/q
    echo.
    echo 删除完毕 

    pause
    GOTO END_CASE

:CASE_233

    echo.
    echo " /$$      /$$ /$$$$$$ /$$   /$$ /$$$$$$$$  /$$$$$$  /$$$$$$$   /$$$$$$  /$$$$$$$$ /$$$$$$$$";
    echo "| $$$    /$$$|_  $$_/| $$$ | $$| $$_____/ /$$__  $$| $$__  $$ /$$__  $$| $$_____/|__  $$__/";
    echo "| $$$$  /$$$$  | $$  | $$$$| $$| $$      | $$  \__/| $$  \ $$| $$  \ $$| $$         | $$   ";
    echo "| $$ $$/$$ $$  | $$  | $$ $$ $$| $$$$$   | $$      | $$$$$$$/| $$$$$$$$| $$$$$      | $$   ";
    echo "| $$  $$$| $$  | $$  | $$  $$$$| $$__/   | $$      | $$__  $$| $$__  $$| $$__/      | $$   ";
    echo "| $$\  $ | $$  | $$  | $$\  $$$| $$      | $$    $$| $$  \ $$| $$  | $$| $$         | $$   ";
    echo "| $$ \/  | $$ /$$$$$$| $$ \  $$| $$$$$$$$|  $$$$$$/| $$  | $$| $$  | $$| $$         | $$   ";
    echo "|__/     |__/|______/|__/  \__/|________/ \______/ |__/  |__/|__/  |__/|__/         |__/   ";
    echo "                                                                                           ";
    echo "                                                                                           ";
    echo "                                                                                           ";

    pause
    GOTO END_CASE
:DEFAULT_CASE
    ECHO 未知选项 "%id%"
    pause
    GOTO END_CASE
    
:END_CASE
    VER > NUL # reset ERRORLEVEL
    GOTO :EOF # return from CALL